Published May 27, 2025 © GPL3+

Social Media Sentiment Art Sculpture

An engineering/art project that uses the Bluesky API to gauge general sentiments in social media for display using lights and servos.

IntermediateShowcase (no instructions)20 hours38

Things used in this project

Hardware components

Particle Photon 2

LED Strip, NeoPixel Digital RGB

I used 3 NeoPixel LEDs wired in series

SparkFun Snappable Protoboard

I soldered all components to a protoboard

TaydaElectronics DC POWER JACK 2.1MM BARREL-TYPE PCB MOUNT

I used this to power the board without being plugged into my computer

Adafruit Continuous Rotation Micro Servo - FS90R

I used this for rotating the apple

Circular Connector Cable Seal, Heat Shrinkable Sealing Boot

Applied these to the solders to keep them from breaking

Female Header 8 Position 1 Row (0.1")

I used female headers to attach the micro controller to the protoboard

Software apps and online services

Particle Build Web IDE

Serial Terminal

Hand tools and fabrication machines

Soldering iron (generic)

Solder Wire, Lead Free

Hot glue gun (generic)

Mainly used hot glue for keeping the components in place and preventing the circuit from breaking

Story

INTRODUCTION/CONCEPT

This project was completed in collaboration with sculpture art students, the visual and decorative components of this project were made by my partner for this project.

This sculpture project was inspired by the theme of "Struggle". To illustrate this theme, we settled to focus on the idea of mental struggles, and how people experience those hardships. We needed to integrate an online data source to inform the physical behavior of our project based on some real-world events or data.

As "mental struggles" are hard to quantify, and finding an API or data source for the topic proved difficult, I settled on building my own API from scratch using social media APIs to construct a real-time "mental health" indicator. My API utilizes the Bluesky API SDK to read recent posts and the VADER sentiment analysis library to determine the sentiment of text. Together, I used these tools to develop an API that can be used to broadly model recent sentiments in social media, usually determining whether a majority of people are happy or sad.

PYTHON SENTIMENT API

The API is essentially a Flask python web server hosted on a personal device that I expose to the internet using a reverse proxy. There's no particular reason to use a reverse proxy over other methods, but it was the easiest to get things working quickly in my use case.

Every day at 12:00 PM the server will request around 500 new posts from Bluesky posted within the last day. It does this by looking for posts with particular mental-health related keywords such as "anxiety" or "stress". Then, it performs sentiment analysis on the text content of each post and saves them into a list. Using these sentiment scores, it can calculate the "sentiment index" in a few ways, such as a simple average or threshold.

Once this index is calculated and stored, navigating to '/get' on the web server will return the value. This way, you can programmatically retrieve the sentiment value from any device with an internet connection.

HARDWARE/FIRMWARE

All the components are wired together on a protoboard. I attached a power jack to ground and VUSB so you can power the micro controller without needing to connect it to USB (make sure to use the proper voltage adapter or you might fry your components, for the Photon 2 that's 5V). The lights are 3 separate RGB LEDs wired in series.

Micro controller and LEDs, the servo is routed through the hole you see near the bottom.

For the firmware, the micro controller will check the sentiment API at the beginning of every new day (12:00 AM). Once it retrieves the current sentiment index, it updates its behavior and the visual appearance of the sculpture.

As the sentiment index increases, the color of the lights will transition from a cool purple color to a warm orange one.

Here the sentiment index is low

Here the sentiment index is high

When the sentiment index is below 0.25, the servo will spin erratically.

When the sentiment index is below 0.5, the servo will spin slowly.

When the sentiment index is above 0.5, the servo will remain stationary.

PROCESS/HOW IT WAS DONE

In the beginning, my first step was to find an API that could supply information about mental health. Due to there not being any easy ones to use, I settled on building my own.

After building the API, I started by wiring my components onto a simple breadboard. This helped give me an idea about the layout of my circuit and plan for writing the firmware.

My initial wiring design with the breadboard

I then wrote the firmware for the micro controller. This included using Particle's "Integrations" system of their cloud service. It is the primary way the Photon 2 interacts with web services. I also used a serial monitor a lot to debug any issues.

The details of the custom webhook in the Particle dashboard

Once the firmware was complete and working, I moved the components onto a protoboard and soldered them together. Then, me and my partner moved the components into the sculpture and hot glued them in appropriate places.

FINAL PRODUCT

Here are some pictures and videos of the project in action:

Visualizing the different states the project can be in

Code

Photon 2 Firmware

#include "Particle.h"
#include <neopixel.h>

#define PIXEL_PIN SPI1 // D2
#define PIXEL_COUNT 3
#define PIXEL_TYPE WS2812B

SYSTEM_MODE(AUTOMATIC);
SerialLogHandler logHandler(LOG_LEVEL_INFO);

Adafruit_NeoPixel strip(PIXEL_COUNT, PIXEL_PIN, PIXEL_TYPE);
Servo continuousServo;

// Functional variables
int currentDay = 0;
unsigned long erraticSpinTargetTime = 0;
bool erraticSpinning = false;
unsigned long lastDebugModeUpdate = 0;
int debugModeState = 0;

// SETTINGS
int minErraticSpinDelay = 100;
int maxErraticSpinDelay = 1250;
int minErraticSpinServo = 40;
int maxErraticSpinServo = 140;

int servoSlowSpin = 95;
int servoStationary = 90;
float erraticSpinUpperRange = 0.25;
float slowSpinUpperRange = 0.5;

int warmColorR = 255, warmColorG = 213, warmColorB = 0;
int coldColorR = 200, coldColorG = 0, coldColorB = 255;

bool debugMode = false;
int debugStateInterval = 3000;
//////

void setStripColor(uint32_t color) {
    for(uint16_t i = 0; i < strip.numPixels(); i++) {
        strip.setPixelColor(i, color);
    }
    strip.show();
}

void setCurrentSentiment(String sentiment) {
    // Gives number between 0 - 1 representing sentiment
    float sentimentValue = sentiment.toFloat();

    // Sets whether to spin erratically or spin servo
    if (sentimentValue <= erraticSpinUpperRange) {
        erraticSpinning = true;
    } else {
        erraticSpinning = false;
        if (sentimentValue <= slowSpinUpperRange) {
            continuousServo.write(servoSlowSpin);
        } else {
            continuousServo.write(servoStationary);
        }
    }
    
    // Interpolates between cold and warm colors
    uint16_t newR = coldColorR + (warmColorR - coldColorR) * sentimentValue;
    uint16_t newG = coldColorG + (warmColorG - coldColorG) * sentimentValue;
    uint16_t newB = coldColorB + (warmColorB - coldColorB) * sentimentValue;
    
    setStripColor(strip.Color(newR, newG, newB));
}

void handleEventResponse(const char *event, const char *data) {
    setCurrentSentiment(String(data));
}

void setup() {
    // Connect to particle
    Serial.begin(9600);
    Particle.subscribe("hook-response/getSentiment/0", handleEventResponse);

    // Attach and setup servo and lights
    continuousServo.attach(D1);
    continuousServo.write(90);
    strip.begin();

    // Demonstrate working lights
    setStripColor(strip.Color(0, 255, 255));
    delay(1000);
    setStripColor(strip.Color(0, 0, 0));
    delay(1000);
}

void loop() {
    if (debugMode) {
        // Cycle between states
        unsigned long currentTime = millis();
        if (currentTime - lastDebugModeUpdate > debugStateInterval) {
            if (debugModeState == 0) {
                setCurrentSentiment(String(erraticSpinUpperRange));
                debugModeState = 1;
            } else if (debugModeState == 1) {
                setCurrentSentiment(String(slowSpinUpperRange));
                debugModeState = 2;
            } else {
                setCurrentSentiment("1");
                debugModeState = 0;
            }
            lastDebugModeUpdate = currentTime;
        }
    } else {
        // Get current day and check if it changes
        int newDay = Time.day();
        if (currentDay != newDay) {
            Particle.publish("getSentiment");
        }
        currentDay = newDay;
    }

    // If we're currently "erraticSpinning", randomly.
    if (erraticSpinning && millis() >= erraticSpinTargetTime) {
        continuousServo.write(random(minErraticSpinServo, maxErraticSpinServo));
        erraticSpinTargetTime = millis() + random(minErraticSpinDelay, maxErraticSpinDelay);
    }
}

Credits

Ali Mostafa

2 projects • 0 followers

Social Media Sentiment Art Sculpture

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

INTRODUCTION/CONCEPT

PYTHON SENTIMENT API

HARDWARE/FIRMWARE

PROCESS/HOW IT WAS DONE

FINAL PRODUCT

Schematics

Circuit Diagram (somewhat)

Code

Photon 2 Firmware

Credits

Ali Mostafa

Comments

Embed the widget on your own site

Social Media Sentiment Art Sculpture

Social Media Sentiment Art Sculpture

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

INTRODUCTION/CONCEPT

PYTHON SENTIMENT API

HARDWARE/FIRMWARE

PROCESS/HOW IT WAS DONE

FINAL PRODUCT

Schematics

Circuit Diagram (somewhat)

Code

Photon 2 Firmware

Credits

Ali Mostafa

Comments

Related channels and tags