Published May 6, 2025 © GPL3+

Bluetooth BLE communication using STM boards

A simple application that uses STM NUCLEO-64 F401RE and a XNUCLEO-IDB5A2 for Bluetooth BLE communication

BeginnerFull instructions provided2 hours215

Bluetooth BLE communication using STM boards

Things used in this project

Hardware components

STM32 XNUCLEO IDB05A2

STMicroelectronics STM32 Nucleo-64 Board

USB-A to Mini-USB Cable

DHT11 Temperature & Humidity Sensor (4 pins)

Software apps and online services

Arduino IDE

Story

This is a simple application of the XNUCLEO-IDB05A2 Bluetooth shield using a STM NUCLEO-64 F401RE board.

The board, the shield and the sensor are connected very simply, remembering the pinout of the DHT11.

1 / 3 • STM32 F401RE

Let's describe the project.

1 / 3

First you need to install the library on Arduino IDE https://github.com/stm32duino/STM32duinoBLE.

In order for the shield to be recognized and used by the board we will have to add a configuration file to our project, as indicated in the example on the site mentioned above.

ble_spi_conf.h file

At this point, just upload an example from the STM32duinoBLE library to Arduino IDE and try.

I have run some of the examples present and based myself on them to realize my project for reading and transmitting temperature and humidity data.

The Arduino IDE configurations are, in this case:

Arduino IDE Configuration

We want to make a simple project to read environmental information (temperature and humidity) and send them using Bluetooth BLE to nearby devices.

Just connect the STM32 F401RE board with the XNUCLEO-IDB05A2 shield with the DHT11 sensor, following the pinout shown and connecting the "Data" pin to digital pin 2 of the Arduino socket.

The code is very simple and is among the attachments.

Arduino IDE and Serial Monitor

Real-time temperature and humidity measurements can be read using a PC or smartphone and a specific app, such as the one shown in the figure:

1 / 3

Code

Temperature and humidity measurement using STM technology

#include <STM32duinoBLE.h>
// Include the DHT11 library for interfacing with the sensor.
#include <DHT11.h>

DHT11 dht11(2);

// Bluetooth® Service
BLEService myService("fff0");

// Bluetooth® Characteristics
// standard 16-bit characteristic UUID; remote clients will be able to get notifications if this characteristic changes
BLEIntCharacteristic Temperature("2A6E", BLERead | BLENotify);
BLEIntCharacteristic Humidity("2A6F", BLERead | BLENotify);

// Temperature and Humidity and timing variable initialization
int t = 27;
int h = 66;
long previousMillis = 0;

void setup() {
  Serial.begin(9600);
  while (!Serial);
  pinMode(LED_BUILTIN, OUTPUT); // initialize the built-in LED pin to indicate when a central is connected
  if (!BLE.begin()) {
    Serial.println("failed to initialize BLE!");
    while (1);
  }
  BLE.setLocalName("Test");
  BLE.setAdvertisedService(myService); // add the service UUID
  myService.addCharacteristic(Temperature);
  myService.addCharacteristic(Humidity);
  BLE.addService(myService);
  Temperature.writeValue(t);
  Humidity.writeValue(h);
  BLE.advertise();
  Serial.println("advertising ...");
}

void loop() {
  BLEDevice central = BLE.central();
   // if a central is connected to the peripheral:
  if (central) {
    Serial.print("Connected to central: ");
    // print the central's BT address:
    Serial.println(central.address());
    // turn on the LED to indicate the connection:
    digitalWrite(LED_BUILTIN, HIGH);

    // check environmental data 2000 ms
    // while the central is connected:
    while (central.connected()) {
      long currentMillis = millis();
      // if 2000 ms have passed, check the values:
      if (currentMillis - previousMillis >= 2000) {
        previousMillis = currentMillis;
        updateLevel();
      }
    }
    // when the central disconnects, turn off the LED:
    digitalWrite(LED_BUILTIN, LOW);
    Serial.print("Disconnected from central: ");
    Serial.println(central.address());
  }
}

//update the environmental values
void updateLevel(){
  int result = dht11.readTemperatureHumidity(t, h);
  // Check the results of the readings.
  // If the reading is successful, print the temperature and humidity values.
  // If there are errors, print the appropriate error messages.
  if (result == 0) {
      Serial.print("Temperature: ");
      Serial.print(t);
      Serial.print(" °C\tHumidity: ");
      Serial.print(h);
      Serial.println(" %");
      Temperature.writeValue(100*t);
      Humidity.writeValue(100*h);
  } else {
      // Print error message based on the error code.
      Serial.println(DHT11::getErrorString(result));
    }
}